え〜、どうやってやんの？ と思っていたらやり方は簡単だった。ちぇっ、つまんないの。

urlショートカットをテキストエディタで開くと次の通り。

    [InternetShortcut]
    URL=http://www.bekkoame.ne.jp/~ilgg

要は上の内容をテキスト形式で、"url" という拡張子でファイルに書き込んでやればよい。

'---------------------------------------------------------------
'  関数名： CreateURLShortCut
'   機能 ： urlショートカットを作成する
'   引数 ： (in) URL_File … urlファイル名(フルパス)
'           (in) HP_Address … ホームページのアドレス
'  返り値 ： 1…正常終了 ０…エラー
'---------------------------------------------------------------
Public Function CreateURLShortCut(ByVal URL_File As String, ByVal HP_Address As String) As Long

    On Error GoTo ErrHandler

    Dim FileNum As Integer

    '拡張子がついていなければ付けてやる
    If UCase$(Right$(URL_File, 4)) <> ".URL" Then
        URL_File = URL_File & ".url"
    End If

    'ファイルナンバー割り当て
    FileNum = FreeFile

    Open URL_File For Output As #FileNum
        Print #FileNum, "[InternetShortcut]"
        Print #FileNum, "URL=" & HP_Address
    Close #FileNum

NormalExit:
    CreateURLShortCut = 1
    Exit Function

ErrHandler:
    Call MsgBox("ｴﾗｰNo." & Err.Number & vbCrLf & vbCrLf & _
        Err.Description, vbExclamation, "urlショートカットを作成 - エラー")

End Function